Welcome Soldier.



TUTORIAL (AMX Mod X - Scripting ) | Programación para principiantes

Fury Ausente
User
#1
Information 
Esto se lo robé a Alucard de este post.

Que a su vez es una tracucción de este post de joaquim



Cabe aclarar que posiblemente en algunas partes no lo traduzca textualmente, cambie un poco las palabras y la explicacion pero siempre llevando al mismo objetivo.



En la programación, todo esta representado por números. Una letra es un numero, una palabra es un grupo de números, un color es un grupo de 3 números (RGB = Red, Green, Blue = Rojo, Verde, Azul). Entonces para programar hay que tratar con números.



PARTE 1 - Variables, Números y Numeros de Arrays



Para poder guardar un numero, tenemos que buscar el lugar donde guardarlo... y ese lugar es denominado variable. Hacemos lo siguiente:

Código PHP:
Código:
new NombreVariable 


new significa que estamos creando una nueva variable.

NombreVariable es el nombre que le asignamos a la variable que creamos.

* Le podemos poner cualquier nombre, pero siempre es conveniente usar el nombre mas apropiado, dependiendo del uso de esta y de lo que queramos guardar adentro.



Esto es llamado declaración de una variable.



Ahora, para guardar un numero dentro de esta variable hacemos lo siguiente:

Código PHP:
Código:
NombreVariable = 5 


* El 5 es solo un ejemplo.

* Le podemos asignar el numero a la variable apenas la creamos o luego de crearla, acá un ejemplo asignándole el numero en el momento que creamos la variable:

Código PHP:
Código:
new NombreVariable = 5 


Ahora, para tener un grupo de números, necesitamos hacer uso de los arrays... de la siguiente forma:

Código PHP:
Código:
new GrupoVariable[x] 


* En x iría el numero que quieran, o que necesiten usar. Obviamente x no va, es solo un ejemplo.

* Ese numero representa el numero de grupos que va a contener esa variable.

* Y cada grupo puede contener un numero...



Para acceder a cada grupo debemos hacer lo siguiente:

Código PHP:
Código:
new Color[3] // creamos una variable con un array de 3 grupos



// Ahora para asignarle un numero a cada grupo:



Color[0] = 255

Color[1] = 0

Color[2] = 0



// Como se habrán dado cuenta, se empieza desde 0... por lo que el ultimo numero desaparece.



// O sino también podríamos hacer así:



new Color[3]



Color = { 255, 0, 0 }



// Y por ultimo también así:



new Color[3] = { 255, 0, 0 } 


Pawn nos provee de operadores aritméticos, entonces podemos hacer algo así:

Código PHP:
Código:
new Color[3]



Color[0] = Color[0] - 10

Color[1] = Color[1] - 10

Color[2] = Color[2] - 10 



// Entonces antes de crear nuestro color podemos hacerlo mas oscuro, restandole una cantidad de 10 en cada monto de color

// Ahora si queremos hacer lo mismo con varios colores, terminaría siendo re largo... por eso podemos crear algo llamado "funcion" de esta forma:



OscurecerColores(Color[3])

{

    Color[0] = Color[0] - 10

    Color[1] = Color[1] - 10

    Color[2] = Color[2] - 10 

}



// Color[3] es solo un nombre que no necesariamente se tiene que usar, ahí van a ir los distintos colores que uno va a usar.

// Entonces al crear esa función, después la podemos a usar de forma simple para oscurecer distintos colores, de la siguiente forma:



// Primero creamos las variables de los colores con sus arrays y sus valores de color.



new UnColor[3] = { 100, 100, 100}

new OtroColor[3] = { 50, 100, 150}

new OtroColorMas[3] = { 255, 30, 233}



// Y después para oscurecerlos con la función que habíamos creado es simplemente así:



OscurecerColores(UnColor)

OscurecerColores(OtroColor)

OscurecerColores(OtroColorMas) 



// Esto automaticamente le resta 10 a cada valor de color.

// Entonces los colores quedarían así:



/*



UnColor = 90 90 90

OtroColor = 40 90 140

OtroColorMas = 245 20 223

*/ 


Con este code anteriormente mostrado, tenemos un problema con la función creada. El problema es que si uno de nuestros colores tiene un numero como por ejemplo 0, al usar la función OscurecerColor, el color valor de tal color va a quedar en negativo (-10) y los valores de color deben ir entre 0 y 255. Así que para eso debemos ponerle determinadas condiciones dentro de la función para que no suceda esto... y se hace de la siguiente forma:

Código PHP:
Código:
OscurecerColores(Color[3])

{

    Color[0] = Color[0] - 10

    Color[1] = Color[1] - 10

    Color[2] = Color[2] - 10 

    

    if(Color[0] < 0)

    {

        Color[0] = 0

    }

    

    if(Color[1] < 0)

    {

        Color[1] = 0

    }

        

    if(Color[2] < 0)

    {

        Color[2] = 0    

    }



// Agarremos una condición de ejemplo:



/* 



    if(Color[0] < 0)

    {

        Color[0] = 0

    }



*/



// Lo primero es la condición, quiere decir que si el primer valor es menor de 0 se cumple lo de abajo.

// Y lo de abajo setea ese valor a 0. Entonces si el valor es menor a 0 (negativo) esta condición hace que se quede en 0 y no se reste mas.



Ahora, para hacer que la función sea mas practica, les voy a dar el siguiente ejemplo:

Código PHP:
Código:
OscurecerColores(Color[3], parametro)

{

    Color[0] = Color[0] - parametro

    Color[1] = Color[1] - parametro

    Color[2] = Color[2] - parametro

}



// Con esto hacemos que sea mas dinámico y que no necesariamente le reste 10, sino que le reste lo que queramos cuando usemos la función para oscurecer tal color...

// Un ejemplo claro seria:



new UnColor[3] = { 100, 100, 100}



OscurecerColores(UnColor, 30)



// Entonces el color nos quedaria: 70 70 70

// Tambien podriamos hacer algo asi:



OscurecerColores(Color[3], parametro1, parametro2, parametro3)

{

    Color[0] = Color[0] - parametro1

    Color[1] = Color[1] - parametro2

    Color[2] = Color[2] - parametro3

}



new UnColor[3] = { 100, 100, 100}



OscurecerColores(UnColor, 30, 50, 10)



// Y nos quedaría así: 70 50 90

// Esto es para que entiendan la forma en la que se puede agregar los distintos parámetros en una función que creemos... 


Ah todo esto, obviamente podemos crear la misma función pero en vez de que sea para oscurecer, podemos hacer que "ilumine" o sea, que el color sea mas clorita. Y simplemente tenemos que cambiar el signo menos por el mas, de la siguiente forma:

Código PHP:
Código:
OscurecerColores(Color[3], parametro1, parametro2, parametro3)

{

    Color[0] = Color[0] + parametro1

    Color[1] = Color[1] + parametro2

    Color[2] = Color[2] + parametro3



Obviamente al hacer esto también vamos a tener el problema de que no tiene que superar los 255 del valor de cada color... por lo que tenemos que aplicar las mismas condiciones que hicimos antes pero en vez de usar el signo < debemos usar el > y para dar un pequeño ejemplo:

Código PHP:
Código:
if(Color[0] > 255) // Si el valor del color supera los 255

    {

        Color[0] = 255 // Se setea lo máximo (255)

    } 




PARTE 2 - Caracteres, Strings, Arrays de caracteres





Definición de string:



Un string es definido como un grupo de 2 o mas caracteres continuos. En programación, un string es solo un array de números que están representados como un conjunto de ellos. Cada carácter en el conjunto de caracteres ASCII es representado por un valor entero en el rango de 0 y 255. En esta parte del tutorial vamos a solo considerar letras del alfabeto a pesar de que el conjunto de caracteres ASCII tiene muchos otros tipos de caracteres (incluyendo números y caracteres de puntuación). Al final de un string hay un carácter nulo, siempre... también conocido como EOS (End of String) y el valor en ASCII es de 0.



Cuando se define un array, en la cual se va a guardar un string, siempre hay que agregar 1 numero mas al tamaño del array (o grupos, o espacios, o slots, o elementos, o como los quieran llamar ><), ya que hay se va a guardar ese carácter nulo que queda al final del string. Un ejemplo: Si quieren guardar en un string la palabra "auto", deben definir el array de una nueva variable, szVariable[5]. Como ven auto tiene solo 4 letras, pero el array que creamos contiene 5, ya que como dijimos le tenemos que agregar 1 mas, el cual va a contener ese carácter nulo. Cuando declaramos un array, por defecto cada elemento/grupo/espacio en el array tiene el valor de 0 (nulo), por ese motivo no se necesita setear manualmente el ultimo valor a 0. Acuérdense siempre de que un array siempre comienza por el 0, entonces un array definido con un tamaño de 5 va a ser ordenado desde el 0 hasta el 4 y el 5 va a ser nulo (0)... [ 0 , 1 , 2 , 3 , 4 ].



Conjunto de caracteres ASCII:



Siempre tengan en cuenta que los caracteres en mayúscula y en minúscula son considerados totalmente distintos. Ejemplo: 'a' no es lo mismo que 'A'



Valores enteros de caracteres ASCII:



El rango de A-Z en valores enteros es de 65-90. 65 es 'A' y 90 es 'Z'

El rango de a-z en valores enteros es de 97-122. 97 es 'a' y 122 es 'z'



Definición de strings con ejemplos de codigo:



Supongan que queremos definir un string y guardar la palabra "auto" o "AUTO".



Lo podemos hacer de 2 formas:



1. Si vas a asignar un valor de string a tu variable cuando la creas, no necesitas de especificar el tamaño del array. El compilador lo hace automáticamente, y también incluye el elemento extra para el carácter nulo al final.

Código PHP:
Código:
new szVariable[] = "auto"

new szVariable[] = "AUTO" 


* Como verán, siempre cuando asignan un valor de string lo deben hacer encerrándolo con comillas.

* el "sz" al comienzo del nombre de la variable no es obligatorio, pero generalmente se usa para saber que esa variable contiene un string. Es una buena costumbre en programación.



2. Ahora vamos a crear un array de 5 elementos. Fíjense como creamos la variable, usando 1 numero mas al tamaño del array, ya que es necesario por lo previamente explicado.

Código PHP:
Código:
szVariable[0] = 97  // a

szVariable[1] = 117  // u

szVariable[2] = 116  // t

szVariable[3] = 111  // o

szVariable[4] = 0    // nulo .. Esto no es necesario ya que el valor default es 0 como dijimos antes.



szVariable[0] = 65  // A

szVariable[1] = 85  // U

szVariable[2] = 84  // T

szVariable[3] = 79  // O

szVariable[4] = 0   // nulo .. Esto no es necesario ya que el valor default es 0 como dijimos antes.



// Cabe aclarar que no necesitas memorizar los valores de ASCII por cada carácter.

// Podes asignar un carácter a cada elemento del array usando las comillas simples. Ejemplo:



szVariable[0] = 'a'

szVariable[1] = 'u'

szVariable[2] = 't'

szVariable[3] = 'o'

szVariable[4] = '^0' 



// Obviamente este ultimo también es nulo y no es necesario declararlo,

// pero es para que entiendan su funcionamiento y estructura 


String terminado en carácter nulo:



Como mencionamos antes, cuando un carácter nulo (valor 0) en encontrado en el array, es considerado el final del string.



Para verlo en acción, acá un pequeño ejemplo:

Código PHP:
Código:
new szVariable[] = "terrorista"



szVariable[6] = 0



// Le seteamos el valor 0 (nulo) al carácter 'o'

// Ya que la estructura de tal string, es así:



szVariable[0] = 't'

szVariable[1] = 'e'

szVariable[2] = 'r'

szVariable[3] = 'r'

szVariable[4] = 'o'

szVariable[5] = 'r'

szVariable[6] = 'i' // Acá

szVariable[7] = 's'

szVariable[8] = 't'

szVariable[9] = 'a'



// Entonces al setearle el carácter 'o' a nulo, logramos que el string quede así:

// "terror" en vez de "terrorista" 


Loopeando a través de los caracteres de un string:



Al hacer un loop, hacemos una acción repetida (una X cantidad de veces seteada en esta bool) recorriendo X cosa, en este caso los caracteres de un string. Uno por uno, carácter por carácter, y en el ejemplo siguiente se va a mostrar como hacer esto e ir contando el numero de letras y espacios que se encuentran dentro del string. Podemos hacer esto de 2 maneras diferentes, usando condiciones (if/else) o switch.



La estructura del loop es la siguiente: for ( expresion1 ; expresion2 ; expresion3).



Explicación de las expresiones:



expresion1: Evaluada solo una vez, antes de de que comience el loopeo. Esto es usado para declarar una variable que usamos en el loop.

expresion2: Evaluada antes de cada iteracion. El loopeo es continuo hasta que esta expresion devuelva el valor de false (falso). Es decir que esta condicion no se cumpla... ya que esta expresion seria una condicion.

expresion3: Evaluada despues de cada iteracion. Normalmente usado para incrementar el indice de la variable que fue declarada en la expresion1.



Nota: Se pueden omitir todas las expresiones de una loop lo cual produce un loop infinito (bucle infinito): for ( ; ; ) [No intentes esto mientras no sepas lo que estas haciendo!]

Código PHP:
Código:
// Expresion1: Declaramos "i" como la variable que vamos a usar para titular al indice del array (tiene el valor de 0 por defecto).

// Expresion2: Continua repitiendose hasta que "i" sea mayor a 9 ( i > 9 ). El loop va a continuar mientras "i" sea menor o igual a 9 ( i <= 9 ).

// Expresion3: Si la condicion de la expresion2 se cumple, la variable "i" incrementa a 1 por cada loopeo.



// Ejemplo:



for ( new i ; i <= 9 ; i++ )

{

        // Aca va el codigo que se repite por cada iteracion

}



// Con este loop, el codigo va a empezar con i = 0, despues ejecuta el codigo que esta en el bloque y luego vuelve a la linea del for-loop para evaluar la condicion de la expresion2.

// Si la condicion de la expresion2 da el valor de true (verdadero), evalua la expresion3 y procede a ejecutar devuelta, el codigo que esta en el bloque.

// Esto continua hasta que la expresion2 de el valor de false (falso). Es decir, hasta que i (0) llegue hasta 9 (ya que por cada iteracion "i" incrementa en 1 


strlen() es una funcion que esta integrada en el AMXX Core (el nucleo del amxx), esta funcion devuelve la longitud de un string, es decir la cantidad de caracteres que tiene un string (excluyendo al valor nulo).

Código PHP:
Código:
new szString[] = "esto es un string"

new iLongitud = strlen( szString )

new iEspacios;

new iLetras_t;



for ( new i = 0 ; i < iLongitud ; i++ )

{

        if ( szString[i] == ' ' )

                iEspacios++

        else if ( szString[i] == 't' )

                iLetras_t++

}



// Comienza de 0 y loopea mientras el indice de la variable "i" sea menor a la longitud del string de la variable szString[]

// Usamos "<" y no "<=" ya que siempre tiene que ser un numero menor porque como se deben acordar el ultimo elemento es nulo



// O tambien podemos usar switch en vez de if/else:



for ( new i = 0 ; i < iLongitud ; i++ )

{

        switch ( szString[i] )

        {

                case ' ': iEspacios++

                case 't': iLetras_t++

        }

}



// El resultado de esto (de cualquiera de las 2 formas) es:

// Espacios = 3 y Letras 't' = 2

// Podemos mostrar este resultado agregando un client_print despues del loop:



client_print(id, print_chat, "Espacios = %i y Letras 't' = %i", iEspacios, iLetras_t) 


Y como otro ejemplo, aca un codigo que crea un string donde guarda todas las minusculas del alfabeto:

Código PHP:
Código:
new szAlfabeto[27] // 26 letras en el alfabeto + un elemento extra para el caracter nulo.



// 'a' tiene un valor en ASCII de 97, entonces solo tenemos que agregarlo

// a nuestro indice del loop, ya que se incrementa con cada paso 



for ( new i = 0 ; i < 26 ; i++ )

        szAlfabeto[i] = i + 97 // Asignamos el valor de ASCII al array y despues incrementamos el valor ASCII de la variable



// Esto es lo que va a ocurrir mientras se ejecuta el loop:



/*

szAlfabeto[0] = 97   // a

szAlfabeto[1] = 98   // b

szAlfabeto[2] = 99   // c

szAlfabeto[3] = 100  // d

...

szAlfabeto[25] = 122 // z

*/



// Creo, que tambien se puede hacer de la siguiente manera:



for ( new i = 0 ; i < charsmax(szAlfabeto) ; i++ )

        szAlfabeto[i] = i + 97



// Ya tambien asi:



for ( new i = 0 ; i < sizeof(szAlfabeto) - 1 ; i++ )

        szAlfabeto[i] = i + 97



// Pero no estoy seguro de esto... cualquiera cosa lo podrian probar 


Array de 2 Dimensiones:



Podes crear un array con varios strings, yo use siempre estos 2 terminos en ingles ya que creo que es la mejor manera de aprender, conociendolos por estos nombres... sin embargo si quieren una correcta traduccion de estos 2 terminos a "Array de Strings" lo pueden entender como "Matriz de Cadenas".



Esto es conocido como un array de dos dimensiones. Un ejemplo:

Código PHP:
Código:
// Para definir el string en un array de dos dimensiones, asignamos el valor del string cuando la creamos:



new szString[][] = { "esto" , "es" , "un" , "array" , "de" , "dos", "dimensiones" }



// Los strings son accesibles mediante el index de dicho string

// Ejemplo: szString[0] = "esto", szString[1] = "es"



// Estructura:



new szString[numero de strings][Longitud de cada string]



// Recuerden que tambien pueden hacer algo asi por si les es mas comodo:



new szString[][] =

{

        "esto",

        "es",

        "un",

        "array",

        "de",

        "dos",

        "dimensiones"  // El ultimo va sin coma, siempre

}



// Tambien, esto se hace de la misma forma que cuando usamos un array normal.

// Es cuestion de entender el orden de cada cosa, para obtener el string "array", usamos szString[3]

// Y para obtener la letra 'a' de "array" es simplemente szString[3][0] y para la letra 'r' es szString[3][1] y asi sucesivamente 


Hay una numerosa cantidad de funciones integradas en el AMXX Core que hacen mas facil la manipulacion de los strings. Y las pueden ver en este link.



PARTE 3 - Sentencias Condicionales (Condiciones)



Lo Basico:

Las condiciones son sentencias que sirven para decidir si se va a continuar con el codigo establecido dentro de dicha condicion. Son como guias, que determinan el camino del plugin, dependiendo de las condiciones que se usen y dependiendo si se cumplen o no.



Realmente son muy faciles de usar, asi que dificilmente se puede tener complicacion al entenderlas y aplicarlas en un codigo. Aparte de ser una de las cosas que mas se usa, en la creacion de plugins.



Las condiciones pueden ser combinadas entre si... y pueden ser mediante and (y) o mediante or (o).



&& Es el simbolo usado para "y".

|| Es el simbolo usado para "o".



Ejemplo:

Código PHP:
Código:
// x es mayor a 0 o menor o igual a 255

x > 0 || x <= 255



// x es mayor a 15 y g es menor a 10

x > 15 && g < 10



// x es menor a 15

// o g es menor a 0 y g es mayor a -10

x < 15 || g < 0 && g > -10



// x es mayor a 16

// y g es mayor a 10 o g es menor a 0

x > 16 && (g > 10 || g < 0)



// a es mayor a b y c es menor a d y e es menor a f

a > b && c < d && e < f 


Los desiguales tienen un caso especial y pueden usarse de diferente forma:

Código PHP:
Código:
// x es mayor a 0 y menor o igual a 5

x > 0 && x <= 5



// Pero tambien se puede hacer de la siguiente forma

0 < x <= 5 


Esa forma, solo funciona en ciertos rangos de valores especificos.

Y solo funciona con &&, no con ||

Código PHP:
Código:
// x es mayor a 5 o menor a 0 

x > 5 || x < 0 


Las condiciones tambien se pueden usar para chequear que algo no sea verdadero.



! Se usa para lo contrario a verdadero, o sea... False. Es decir, lo opuesto

!= Se usa cuando algo no es igual

Código PHP:
Código:
// x no es menor a 0

!(x < 0)



// x no es igual a 0

x != 0 


Código PHP:
Código:
// x es mayor a 0 y g es menor a 2

x > 0 && g < 2



// Lo mismo que arriba, pero con el operador opuesto:

!(x <= 0 || g >= 2)



// Esta condicion se lee de la siguiente forma:

// Si x <= 0, devuelve false (falso)

// Si g >= 2, devuelve false (falso)

// Sino, devuelve true (verdadero), es decir... si es: x > 0 y g < 2 


Sentencia "IF":

La sentencia de condicion "if" es lo principal para usar las condiciones anteriormente explicadas. Es decir, que es el metodo por el cual se usan. La estructura de las condiciones son de la siguiente forma:

Código PHP:
Código:
if( [condicion] )

{

    // Codigo que se ejecutara si la condicion se cumple

}



// Ahora, un ejemplo de tal estructura:



if( x > 1 )

{

    // Este codigo se ejecutara si x es mayor a 1



Al mismo tiempo tambien esta el "else if" y el "else" que son otras sentencias de condicion, pero que van de la mano. No puede haber un "else if" o un "else" si no hay un "if" previo.

Código PHP:
Código:
if( [condicion 1] )

{

    // condicion #1 es verdadera

}

else if( [condicion 2] )

{

    // condicion #1 es falsa

    // y la condicion #2 es verdadera

}

else

{

    // condicion #1 es falsa

    // y la condicion #2 es falsa

}



// Aunque no necesariamente tiene que haber un "else if"

// Puede ir un if y luego un else, entonces si la condicion del if no se cumple

// Se ejecuta lo que esta dentro del else 


Aca un ejemplo mas para que lo entiendan mejor:

Código PHP:
Código:
new x = 5



if( x > 3 )

{

    // 1

}

else if( x < 4 )

{

    // 2

}

else

{

    // 3

}



// En este caso mostraria lo que esta en el "1". Sin embargo...

// Si cambiamos el 5 de la variable "x" por un 4. Mostraria lo que esta en el "3".



// Otro dato a dar, es que el "else if" puede ser usado mas de una vez.

// No necesariamente tiene que ser 1, esto son solo ejemplos. 


Loops (Bucle):

Hay 3 tipos de loops que se pueden usar, y son los siguientes:



while

do, while

for





La lista esta ordenada en cuestion a la dificultad. Igualmente, no son muy dificiles, sin embargo al principio cuesta un poco entender su funcionamiento, pero principalmente... usarlas/aplicarlas dentro de un plugin.



Los loops, sirven para ejecutar un bloque de codigo, en forma repetitiva. De acuerdo a distintas condiciones y/o parametros que le asignamos.



El loop while continua ejecutando mientras que la condicion se siga cumpliendo, es decir... que de true (verdadero/positivo). La estructura de este loop, es la siguiente:

Código PHP:
Código:
while( [condicion] )

{

    // Bloque de codigo



La forma en la que trabaja el while es la siguiente:



Chequea la condicion establecida

Si la condicion se cumple, ejecuta el codigo; de lo contrario, finaliza el loop

Vuelve al primer paso





Como veran, el while es muy similar al "if", a diferencia de que este se repite constantemente.



El loop do, while es practicamente lo mismo al while.

La unica diferencia es el orden en el que trabaja y se usa:

Código PHP:
Código:
do

{

    // Bloque de codigo

}

while( [condicion] );



// El punto y coma no es necesario, solo si el punto y coma esta forzado en el plugin 


La forma en la que trabaja el do, while es la siguiente:



Ejecuta el codigo dentro

Chequea la condicion establecida

Si la condicion se cumple, ejecuta el codigo; de lo contrario, finaliza el loop

Vuelve al segundo paso





El loop for es mas complicado que los otros loops, sin embargo no es algo realmente dificil. Cuestion de ver, entender y practicar.



Generalmente es usado para contar de un numero a otro (Recuerden que todo representa numeros en la programacion).

El "for" consta de 3 partes (parametros): inicial, condicion, incremento.



Inicial - Creacion de variables para usar en el loop.

Condicion - Sentencia de condicion para chequear si el loop debe continuar.

Incremento - Incrementar el valor de la variable que fue creada.



La estructura del loop "for" es la siguiente:

Código PHP:
Código:
for( [inicial]; [condicion]; [incremento] ) // Los punto y coma en este caso son obligatorios!

{

    // Bloque de codigo



La forma en la que trabaja el for es la siguiente:



Se ejecuta el incial

Si la condicion es cumple, ejecuta el codigo; de lo contrario, finaliza el loop

Ejecuta el bloque de codigo

Ejecuta el incremento

Vuelve al segundo paso





Algunos ejemplos:

Código PHP:
Código:
// Contando de 1 a 5:



for( new i = 1; i <= 5; i++ ) // i++ incrementa la variable i de a 1

{

    // Bloque de codigo

}



// Contando de 10 a 1:



for( new i = 10; i >= 1; i-- ) // i-- decrece la variable i de a 1

{

    // Bloque de codigo




Dentro de los loops, se puede forzar para que una parte del codigo sea salteada y se vuelva a la condicion del loop. Esto se hace con el operador "continue":

Código PHP:
Código:
for( new i = 0; i < 4; i++ )

{

    if( i == 2 )

    {

        continue;

    }

    

    // Bloque de codigo que se ejecutara excepto cuando i sea igual a 2

    // Es decir que se va a ejecutar cuando i sea igual a 0, 1, 3 y 4



Dentro de los loops, tambien se puede forzar a que finalice dicho loops, si se cumple cierta condicion, con el operador "break":

Código PHP:
Código:
for( new i = 0; i < 4; i++ )

{

    if( i == 2 )

    {

        break;

    }

    

    // Este codigo solo se ejecutara cuando la variable i es igual a 0 y 1

    // Cuando la variable i es igual a 2, el loop finaliza



Sentencia "Switch":

Los switch son para determinar ciertos bloques de codigos dependiendo el resultado que de una funcion, una variable, etc... Son practicamente iguales al if. En muchos casos es mas comodo, prolijo, facil, etc... usar switch que conficiones con IF:

Código PHP:
Código:
switch( variable ) // No necesariamente tiene que ser una variable, puede ser una funcion directamente

{

    case VALOR1:

    {

        // variable es igual a VALOR1

    }

    case VALOR2:

    {

        // variable es igual a VALOR2

    }

    case VALOR3:

    {

        // variable es igual a VALOR3

    }

}



// En el caso del switch, en vez de else, aca se usa "default":



switch( variable ) // No necesariamente tiene que ser una variable, puede ser una funcion directamente

{

    case VALOR1:

    {

        // variable es igual a VALOR1

    }

    case VALOR2:

    {

        // variable es igual a VALOR2

    }

    default:

    {

        // variable no es igual a ninguno de los otros case's

        // Es decir que no es ni VALOR1 ni VALOR2

    }



PARTE 4 - Operadores Matematicos



Lo Basico:

Como todos saben, los operadores matematicos standars son:



Suma

Resta

Multiplicacion

Division





Y pueden ser usados facilmente dentro de la programacion

Código PHP:
Código:
new x = 1, y = 4;



// Suma

x = y + 1; // ahora x es igual a 5



// Resta

y = x - 2; // ahora y es igual a 2



// Multiplicacion

x = y * 2; // ahora x es igual a 4



// Division

y = 12 / x; // ahora y es igual a 3 


En la programacion hay mas operadores matematicos, aparte de los 4 standars mencionados anteriormente:



Modulo

Desplazamiento de bits (Bit Shifting o Bitsum)





El operador Modulo da el valor del resto luego de la division entre dos numeros. Un ejemplo:

Código PHP:
Código:
25 / 4 = 6 R 1

// Esto significa que 25 dividido 4 da 6, ya que

// 4 tiene que multiplicarse 6 veces, sin embargo

// el resultado de esa multiplicacion da 24, y el resto

// de eso es 1. Pero para obtener correctamente el resto

// lo hacemos de la siguiente forma:



new x = 25 % 4;

// x vale 1, ya que es el resto de esa division



x = 113 % 100;

// x vale 13, ya que es el resto de esa division 


En cuanto al operador Bitsum (desplazamiento de bits o como lo quieran llamar) ya hay un tuto que explica esto, traducido por larito, el cual se encuentra en este link.



Incrementos:

Las variables en ciertos momentos deben ser manipuladas, es decir... que a veces necesitamos aumentarlas, restarlas, o cualquier otro uso de operadores matematicos al valor original de dicha variable. Un claro ejemplo seria el siguiente:

Código PHP:
Código:
new x = 5;

// Le asignamos el valor 5 a la variable x



x = x + 1;

// Le incrementamos 1 a la variable x, ahora el valor es de 6



x = x * 2;

// Le multiplicamos por 2 a la variable x, ahora el valor es de 12



x = x / 4;

// Le dividimos por 4 a la variable x, ahora el valor es de 3



x = x - 2;

// Le restamos 2 a la variable x, ahora el valor es de 1 


Pero esto lo podemos simplificar aun mas, de una forma mas rapida y sencilla, que es la siguiente:

Código PHP:
Código:
variable (operador)= valor;

// Como veran aca se hace la operacion directamente,

// sin tener que poner nuevamente la variable a modificar

// es practicamente como hacer valor (operador) valor solo

// que en este caso el resultado se le asigna a la variable 


Ejemplo:

Código PHP:
Código:
new x = 5;

// Le asignamos el valor 5 a la variable x



x *= 10;

// Multiplicamos la variable x por 10, ahora da 50



x -= 10;

// Restamos 10 a la variable, ahora da 40



x /= 2;

// Dividimos la variable por 2, ahora da 20



x += 4;

// Aumentamos 4 a la variable, ahora de 24 


Pero en ciertos casos, cuando necesitamos aumentar o restar una variable + 1, hay una forma aun mas sencilla que es la siguiente:

Código PHP:
Código:
new x = 1;

// Le asignamos el valor 1 a la variable x



x++;

// De esta forma se aumenta + 1 a la variable,

// por lo que ahora el valor de x es 2

// ++ es el equivalente a hacer "+= 1" o "+ 1"

// dependiendo el metodo que usemos de los ya

// explicados anteriormente



// Aparte de eso, el ++ puede ser usado antes de

// la variable, como en el siguiente ejemplo:



++x;



// Sin embargo, hay una cierta diferencia entre estas 2

// formas, ++variable incrementa la variable ANTES de ser

// usada, en cambio variable++ aumenta la variable DESPUES

// de ser usada, ver los siguientes ejemplos para su entendimiento:



new x = 1;

new y = x++;

// x = 2, y = 1

// "x" fue incrementado a 2 DESPUES de ser asignado a "y"



x = 1;

y = ++x;

// x = 2, y = 2

// "x" fue incrementado a 2 ANTES de ser asignado a "y" 


Y obviamente, lo mismo va para el -= 1, el uso de los dos --

Código PHP:
Código:
new x = 1;

new y = --x;

// x = 0, y = 0



x = 10;

y = x--;

// x = 9, y = 10 


post: https://amxmodx-es.com/Thread-Programaci...ncipiantes

"El día que seas capaz de llorar de impotencia ante una injusticia, ese día seremos compañeros"
Responder

isr4el Sin conexión
User
#2
._. ..
100% michoacano  
Responder

ChrstopH Ausente
Hypnotize
#3
deberías agregarle otro ejemplos más básicos, como en que caso usar los if , else if o cascadas, switch, dor do while y while, ya que no todos tienen buena lógica & con eso haces que la comprensión sea más rápida..

aparte el titulo debería decir introducción al amx mod scripting o como se llame..
[Imagen: 76561198283253977.png]

Mapas Frutas 100%
DeathRun Levels 100%
Atrapa al Traidor (Edición) 100%
Battle Royale 40%
Responder

Fury Ausente
User
#4
(06-26-2017, 07:46 PM)ChrstopH escribió: deberías agregarle otro ejemplos más básicos, como en que caso usar los if , else if o cascadas, switch, dor do while y while, ya que no todos tienen buena lógica & con eso haces que la comprensión sea más rápida..

aparte el titulo debería decir introducción al amx mod scripting o como se llame..

Tienes razón.
Gracias por la sugerencia bb :interesting:

"El día que seas capaz de llorar de impotencia ante una injusticia, ese día seremos compañeros"
Responder

PlayEasymx Sin conexión
User
#5
No creo que usar variables sea de principiantes.. switch ni todo ese pedo la malloria..
Como dice chris, te falto las if, else if, prechachear un sonido ya sea mp3 o .wav, falto para reproducirlos, tanto para mp3 y wav,
dar dinero, sacar dinero, ver el dinero, etc etc, lo mas basico es creo crear un cmd y mendar un menssaje.
Responder

[F]orget Sin conexión
User
#6
(07-07-2017, 01:52 AM)PlayEasymx escribió: No creo que usar variables sea de principiantes.. switch ni todo ese pedo la malloria..
Como dice chris, te falto las if, else if, prechachear un sonido ya sea mp3 o .wav, falto para reproducirlos, tanto para mp3 y wav,
dar dinero, sacar dinero, ver el dinero, etc etc, lo mas basico es creo crear un cmd y mendar un menssaje.

ola me gustaria que alguien me ayudara a crear plugins en amxx plox agregenme a steam para recibir acesorias de amxx scripting
:excitedeyes: :excitedeyes: :excitedeyes: :excitedeyes:
 "pedes tener muchas vidas extras en un videojuego. pero en la vida real no hay vidas extra aprovechala"
Responder

GabsHp Sin conexión
Lord Gabs
#7
(04-15-2018, 04:23 AM)[F]orget escribió:
(07-07-2017, 01:52 AM)PlayEasymx escribió: No creo que usar variables sea de principiantes.. switch ni todo ese pedo la malloria..
Como dice chris, te falto las if, else if, prechachear un sonido ya sea mp3 o .wav, falto para reproducirlos, tanto para mp3 y wav,
dar dinero, sacar dinero, ver el dinero, etc etc, lo mas basico es creo crear un cmd y mendar un menssaje.

ola me gustaria que alguien me ayudara a crear plugins en amxx plox agregenme a steam para recibir acesorias de amxx scripting
:excitedeyes: :excitedeyes: :excitedeyes: :excitedeyes:

Es más difícil que alguien te lo explique, lo puedes aprender tu mismo modificando algunos plugins ya creados. Con eso vas agarrando practica y te familiarizas con el lenguaje.
Responder





Usuarios navegando en este tema:
1 invitado(s)



Sobre M X E M E X I C O

Comunidad MxE © 2020 - La mejorar comunidad de Counter Strike 1.6 .